home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / CRS / crs59.d81 / pspm2geo (.txt) < prev    next >
Commodore BASIC  |  2009-10-10  |  4KB  |  110 lines
  1. 10 L1=0:L2=88:AD=22528:POKE53281,0:POKE53280,0:PRINT"[147]"
  2. 20 PRINT"     [158][176][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][174]"
  3. 30 PRINT"     [194] PRINT SHOP AND PRINTMASTER [194]"
  4. 35 PRINT"     [194]      TO GEOS CONVERTER     [194]"
  5. 40 PRINT"     [173][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][189]"
  6. 50 FOR N=1TO11:PRINT:NEXT:GOTO190
  7. 60 FF=0:PRINT#15,"U1:2 0"+STR$(T)+STR$(S)
  8. 70 GET#2,A$:TN=ASC(A$+CHR$(0)):GET#2,A$:SN=ASC(A$+CHR$(0))
  9. 80 FORN=0TO7:PRINT#15,"B-P:2,"+STR$(32*N+2)
  10. 90 GET#2,A$:IFA$<>CHR$(131)THEN160
  11. 100 GET#2,A$:TP=ASC(A$+CHR$(0)):GET#2,A$:SP=ASC(A$+CHR$(0)):H$=""
  12. 110 GET#2,A$:IFA$<>CHR$(160)THENH$=H$+A$:GOTO110
  13. 120 IFH$<>DI$THEN160
  14. 130 FF=1:KP=N:N=7
  15. 140 PRINT#15,"B-P:2,"+STR$(32*KP+30)
  16. 150 GET#2,A$:SL=ASC(A$+CHR$(0)):GET#2,A$:SH=ASC(A$+CHR$(0))
  17. 160 NEXT:IFTN=0THENRETURN
  18. 170 IFFF=1THENRETURN
  19. 180 T=TN:S=SN:GOTO60
  20. 190 PRINT"[145][145][145][145][145][145][145][145][145]     PLACE PRINT SHOP OR PRINTMASTER "
  21. 195 PRINT"            DATA DISK IN DRIVE"
  22. 200 PRINT"        PRESS RETURN[146] WHEN READY..."
  23. 210 GETA$:IFA$<>CHR$(13)THENGOSUB970:GOTO210
  24. 220 POKE53280,0
  25. 230 PRINT"[147]  ARE THESE GRAPHICS FOR A C[146]OMMODORE"
  26. 240 PRINT"           OR O[146]THER PRINTER?"
  27. 245 PRINT"     (CHOOSE O[146]THER FOR PRINTMASTER)";
  28. 250 GETA$:IFA$="C"THENSF=2:W=6:H=45:GOTO280
  29. 260 IFA$="O"THENSF=3:W=11:H=52:GOTO280
  30. 270 GOTO250
  31. 280 NL=INT(H/8+1)*8:PRINT"[147]"
  32. 290 PRINT"TYPE FILE NAME OR PRESS RETURN[146] FOR LIST":INPUTN$
  33. 300 IFN$=""THENGOSUB680
  34. 310 OPEN8,8,0,N$:OPEN15,8,15:INPUT#15,EN,EB$,ET,ES
  35. 320 IFEN<>0THENCLOSE8:CLOSE15:PRINT"[147]";SPC(20-LEN(EB$)/2)EB$:N$="":GOTO290
  36. 330 PRINT"[147]"SPC(16-LEN(N$)/2)"LOADING "+N$
  37. 332 OPEN2,8,2,N$:GET#2,A$,A$:IFASC(A$+CHR$(0))=135THENL1=98:L2=135:AD=34675
  38. 334 CLOSE2
  39. 335 CLOSE8:OPEN8,8,0,N$
  40. 340 POKE185,0:POKE780,0:POKE781,L1:POKE782,L2:SYS65493:CLOSE8:CLOSE15
  41. 350 PRINT"[147]        PLACE GEOS DISK IN DRIVE"
  42. 360 PRINT"       PRESS RETURN[146] WHEN READY..."
  43. 370 GETA$:IFA$<>CHR$(13)THENGOSUB970:GOTO370
  44. 380 POKE53280,0:PRINT"         SAVING PHOTOSCRAP FILE"
  45. 390 OPEN15,8,15,"I0":INPUT#15,EN,EB$,ET,ES:IFEN<>0THEN1000
  46. 400 OPEN2,8,2,"S,U,W":INPUT#15,EN,EB$,ET,ES:IFEN<>0THEN1000
  47. 410 PRINT#2,CHR$(W)CHR$(NL)CHR$(0)CHR$(2*W)CHR$(0);
  48. 420 FORN=0TOH-1:PRINT#2,CHR$(128+W);:FORM=0TOW-1
  49. 425 IFL1=98THENAD=AD+1:PRINT#2,CHR$(PEEK(AD));:NEXT:AD=AD+1:NEXT
  50. 430 IFL1<>98THENPRINT#2,CHR$(PEEK(AD+W*N+M));:NEXT:NEXT
  51. 440 PRINT#2,CHR$((NL-H-2)*W)CHR$(0)CHR$(W*NL/8)CHR$(191)CHR$(0);:CLOSE2
  52. 450 DATA80,104,111,116,111,32,83,99,114,97,112
  53. 460 P$="":FORN=0TO10:READX:P$=P$+CHR$(X):NEXT
  54. 470 OPEN2,8,2,"#":T=18:S=1:DI$=P$:GOSUB60
  55. 480 IFFF=0THENPRINT"NO PHOTO SCRAP FILE":GOTO640
  56. 490 T1=T:S1=S:FS=256*SH+SL-1:T2=TP:S2=SP:K1=KP
  57. 500 T=18:S=1:DI$="S":GOSUB60
  58. 510 PRINT#15,"B-P:2,"+STR$(32*KP+3)
  59. 520 PRINT#2,CHR$(T2)CHR$(S2);
  60. 530 PRINT#15,"B-P:2,"+STR$(32*KP+30)
  61. 540 FH=INT(FS/256):FL=FS-256*FH
  62. 550 PRINT#2,CHR$(FL)CHR$(FH);
  63. 560 PRINT#15,"U2:2 0"+STR$(T)+STR$(S)
  64. 570 PRINT#15,"U1:2 0"+STR$(T1)+STR$(S1)
  65. 580 PRINT#15,"B-P:2,"+STR$(32*K1+3)
  66. 590 PRINT#2,CHR$(TP)CHR$(SP);
  67. 600 PRINT#15,"B-P:2,"+STR$(32*K1+30)
  68. 610 PRINT#2,CHR$(SF+1)CHR$(0);
  69. 620 PRINT#15,"U2:2 0"+STR$(T1)+STR$(S1)
  70. 630 PRINT#15,"S0:S"
  71. 640 CLOSE2:CLOSE15
  72. 650 PRINT"[147]DONE"
  73. 660 PRINT"    PLACE GEOS[146] MASTER DISK IN DRIVE"
  74. 670 PRINT"       HIT RESTORE[146] TO REBOOT GEOS":END
  75. 680 OPEN15,8,15,"I0":OPEN2,8,2,"#":X=0:M=0:T=18:S=1:N=0
  76. 690 PRINT"[147]  THE GRAPHIC FILES ON THIS DISK ARE:"
  77. 700 PRINT#15,"U1:2 0"+STR$(T)+STR$(S)
  78. 710 GET#2,A$:TN=ASC(A$+CHR$(0)):GET#2,A$:SN=ASC(A$+CHR$(0))
  79. 720 PRINT#15,"B-P:2,"+STR$(N*32+2)
  80. 730 GET#2,A$:FT=ASC(A$+CHR$(0)):IF(191ANDFT)<>130THENN=N+1:GOTO810
  81. 740 PRINT#15,"B-P:2,"+STR$(N*32+30)
  82. 750 GET#2,A$:FS=ASC(A$+CHR$(0)):GET#2,A$:FS=FS+256*ASC(A$+CHR$(0))
  83. 760 IFFS<>SFTHENN=N+1:GOTO810
  84. 770 PRINT#15,"B-P:2,"+STR$(N*32+5):D$=""
  85. 780 GET#2,A$:IFA$<>CHR$(160)THEND$=D$+A$:GOTO780
  86. 790 X=X+1:M=M+1:IFM=16THENM=0:GOTO840
  87. 805 PRINT"   "+CHR$(34)+D$+CHR$(34):N=N+1
  88. 810 TY=0:IFN<8THEN720
  89. 820 N=0:T=TN:S=SN:IFT<>0THEN700
  90. 830 IFT=0THEN860
  91. 840 PRINT"        PRESS RETURN[146] TO SEE MORE"
  92. 850 PRINT"    TYPE _ AND PRESS RETURN[146] TO ABORT"
  93. 860 IFX=0THENPRINT"        NONE":GOTO930
  94. 870 PRINT"      PLACE CURSOR NEXT TO NAME OR"
  95. 880 PRINT"   TYPE NAME AND PRESS RETURN[146] TO LOAD":INPUTN$
  96. 890 IFN$="_"THENN$="":GOTO920
  97. 900 IFN$<>""THENCLOSE2:CLOSE15:RETURN
  98. 910 IFT<>0THEN690
  99. 920 PRINT"[147]";
  100. 930 CLOSE2:CLOSE15:PRINT"    PLACE ANOTHER DATA DISK IN DRIVE"
  101. 940 PRINT"       PRESS RETURN[146] WHEN READY..."
  102. 950 GETA$:IFA$<>CHR$(13)THENGOSUB970:GOTO950
  103. 960 POKE53280,0:GOTO680
  104. 970 A=A+1:IFA>10THENPOKE53280,2
  105. 980 IFA>20THENPOKE53280,0:A=0
  106. 990 RETURN
  107. 1000 PRINT"[147]";SPC(20-LEN(EB$)/2)""+EB$
  108. 1010 PRINT"           RESETTING DRIVE..."
  109. 1020 PRINT#15,"UJ":FORN=1TO1500:NEXT:CLOSE15:CLOSE2:GOTO380
  110.